
.cmchar "The gothic letter a";
.beginchar("a",6.278u#,x_height#,0);
.adjust_fit(cap_serif_fit#,cap_serif_fit#-0.3u#);
z0=(0,0); ygoth_a(0); .endchar;

.cmchar "The gothic letter b";
.beginchar("b",6.111u#,1.431x_height#,0);
.adjust_fit(cap_serif_fit#,cap_serif_fit#);
penpos1(stem,0); penpos2(stem,0);
penpos3(stem,0); penpos4(stem,0);
penpos8(stem,60); penpos9(stem,60);
z1=(0.243w,foot); z2=(x1,0.888h);
z9l=z1l-(2apex_o,0);
x7=0.359[x1r,x3l]; y7=-apex_o;
z8l=z7; z3r-z7=whatever*dir30;
x3r=w-apex_o;
z4r=(x3r,0.833x_height);
z7'=whatever[z9r,z8r]; z7'=whatever[z7,z3r];
z7''=whatever[z7,z3r]; x7''=x3l;
penstroke z1e--z2e; penstroke z8e--z9e;
penstroke z3e--z4e;
filldraw z8r--z7'--z7--z8r & cycle;
filldraw z7''--z3l--z3r--z7'' & cycle;
penpos100(hair,angle(z3r-z7)-90);
penpos101(hair,angle(z3r-z7)-90);
z100r=z7; z101r=whatever[z7,z3r]; x101l=x3r;
penstroke z100e--z101e;
%
%
%
penpos5(stem,60); z17=(x1r,0.824x_height);
z6=(0.821[x1r,x3l],x_height);
z5r=(x101r,y4); 
penpos6'(hair,angle(z6-z17)-90);
z6'l=z6; z17'-z6'r=whatever*(z17-z6);
x17'=x1r; z5.1=whatever[z17',z6'r];
z5.1-z5l=whatever*(z6-z5r);
filldraw z5r--z6--z17--z17'--z5.1--z5l--z5r
& cycle;
%
%
%
z21=0.267[z2l,z2r]; z20=(x6,0.5[h,y2]);
penpos20(3/4hair,-135);
z22=(0.545[x21,x20],h-apex_o);
z21'=(x1r,1/4[y21,y6]);
filldraw z21..z22..{down}z20l & z20l--z20r
& z20r{up}..z21'{down} & z21'--z2r--z21 &
cycle;
penpos18(hair,angle(z6-z17));
x18r=0;y18r=1/3[h,y21];
z21''=(x1l,0.5[y21,y6]);
filldraw z21''{up}..{z18-z21}z18l &
z18l--z18r--z21--z2l--z21'' & cycle;
.endchar;

.cmchar "The gothic letter c";
.beginchar("c",4.306u#,x_height#,0);
.adjust_fit(cap_serif_fit#,cap_serif_fit#);
z0=(0,0); ygoth_c(0);
.endchar;

.cmchar "The gothic letter d";
.beginchar("d",6.111u#,1.431x_height#,0);
.adjust_fit(cap_serif_fit#,cap_serif_fit#);
penpos1(stem,0); penpos2(stem,0);
penpos3(stem,0); penpos4(stem,0);
penpos8(stem,60); penpos9(stem,60);
z1=(0.243w,foot); z2=(x1,0.888h);
z9l=z1l-(apex_o,0);
x7=0.359[x1r,x3l]; y7=-apex_o;
z8l=z7; z3r-z7=whatever*dir30;
x3r=w-apex_o;
z4r=(x3r,0.88x_height); %0.833
z7'=whatever[z9r,z8r]; z7'=whatever[z7,z3r];
z7''=whatever[z7,z3r]; x7''=x3l;
penstroke z8e--z9e;
penstroke z3e--z4e;
filldraw z8r--z7'--z7--z8r & cycle;
filldraw z7''--z3l--z3r--z7'' & cycle;
penpos100(hair,angle(z3r-z7)-90);
penpos101(hair,angle(z3r-z7)-90);
z100r=z7; z101r=whatever[z7,z3r]; x101l=x3r;
penstroke z100e--z101e;
%
%
%
penpos5(stem,60); z17=(x1r,0.824x_height);
z6=(0.821[x1r,x3l],x_height);
z5r=(x101r,y4); 
penpos6'(hair,angle(z6-z17)-90);
z6'l=z6; z17'-z6'r=whatever*(z17-z6);
x17'=x1r; z5.1=whatever[z17',z6'r];
z5.1-z5l=whatever*(z6-z5r);
filldraw z5r--z6--z17--z17'--z5.1--z5l--z5r
& cycle;
%
%
%
penpos2'(stem,0); z2'r=z17'; 
z31=whatever[z6,z5r]; x31=x1l;
z30=whatever[z31,z5r]; 
z30-z2'l=whatever*(z2'r-z6'r);
x34=0; z34=whatever[z5.1,z5l];
z32=(x31-0.5hair,y31+hair);
z33=(2x32,y34); z35=whatever[z2'l,z30];
z35=whatever[z34,z5.1];
filldraw z2'r--z6'r--z6--z31--z34--z35
--z2'l--z2'r & cycle;
filldraw z34{up}..z32 & z32..{down}z33 &
z33--z34 & cycle;
penstroke z1e--z2'e;
%
%
%
penpos150(1.2hair,angle(z5.1-z35));
z150l=z35;
unfilldraw z2'r{up}..{z30-z35}z150r & z150r
--z5.1--z2'r & cycle;
unfilldraw z2'r{up}..{z30-z35}z150r & z150r
--z5.1--z2'r & cycle;
.endchar;

.cmchar "The gothic letter e";
.beginchar("e",4.306u#,x_height#,0);
.adjust_fit(cap_serif_fit#,cap_serif_fit#+.7u#);
z0=(0,0); ygoth_e(0);
.endchar;

.cmchar "The gothic letter f";
.beginchar("f",4.389u#,11.944u#,0);
.adjust_fit(cap_serif_fit#,cap_serif_fit#-.2u#);
z0=(hair,0); ygoth_s(0);
penpos260(4/5stem,-90); penpos261(4/5stem,-90);
y260r=y261r=0.732x_height;
x260=x0+apex_o+stem;
x261=x0+apex_o+2stem;
penstroke z260e--z261e;
.endchar;

.cmchar "The gothic letter g";
.beginchar("g",7.556u#,x_height#,3u#);
.adjust_fit(cap_serif_fit#,cap_serif_fit#-0.3u#);
penpos1(stem,0); penpos2(stem,0);
penpos3(stem,0); penpos4(stem,0);
x1l=x2l=apex_o; x3l=x4l=0.574w;
penpos5(1.083stem,63); penpos6(1.083stem,63);
penpos20(2hair,-51); penpos21(2hair,-45);
penpos22(2hair,-28);
y1=0.108x_height; %y2=0.788x_height;
y3=0.235x_height; y4=0.843x_height;
y5r=x_height; x5l=x2r; y2=y5l;
z6r=(w,0.915x_height); y20l=y2; x20=x1l;
z21r=z2r; z22l=whatever[z5r,z5l]; y22l=h+apex_o;
penpos6'(1.083stem,63); 
z6'l=whatever[z5l,z6l]; x6'=x6-hair;
penstroke z1e--z2e; penstroke z3e--z4e;
penstroke z6'e--z5e; penstroke z20e..z21e..z22e;
penpos6''(1.083stem,63); 
z6''=whatever[z6l,z6r]; z6''l=1/5[z6l,z6r]; 
penstroke z6'e{z6-z5}..z6''e;
%
%
%
penpos16(stem,65); z16l=(0,y1);
penpos7(hair,-41);
z7r=(x1l,-d); penpos8(hair,-41); z8l=z3l;
z7'=whatever[z7l,z8l]; y7'=-d; 
filldraw z7'--z8l--z8r--z7r--z7' & cycle;
z15'=whatever[z16l,(x1r,0)]; 
z15'=whatever[z7r,z8r]; z15-z16r=
whatever*(z15'-z16l); z15=whatever[z7r,z8r];
filldraw z16l--z16r--z15--z15'--z16l &
cycle;
penpos9(stem,30); z9l=z3l; 
x12=x6r; z12-z9r=whatever*dir-60;
penpos10(whatever,45); z10r=z12;
z10l-z9l=whatever*(z12-z9r);
z13''=whatever[z7l,z8l]; x13''=x1r;
penpos11'(hair,-45);
z11'r=z12; z11''=whatever[z9l,z10l];
z11''-z11'l=whatever*(z10l-z10r);
penpos13'(stem,angle(z11''-z13'')+90);
z13'r=z13''; z11-z13'l=whatever*(z11''-z13'');
z11=whatever[z10l,z10r]; 
z13=whatever[z7l,z8l];
z13=whatever[z13'l,z11];
filldraw z13--z11--z12--z11'l--z11''--
z13'r--z13 & cycle;
penstroke z10e--z9e;
filldraw z7r{z15-z7r}..z13'l{z11-z13}
& z13'l--z13--z7r & cycle;
.endchar;

.cmchar "The gothic letter h";
.beginchar("h",6.111u#,1.431x_height#,2.778u#);
.adjust_fit(cap_serif_fit#,cap_serif_fit#+0.2u#);
z0=(0,0); ygoth_h(0);
.endchar;

.cmchar "The gothic letter i";
.beginchar("i",2.889u#,1.431x_height#,0);
.adjust_fit(cap_serif_fit#+0.6u#,cap_serif_fit#-.7u#);
penpos1(stem,0); penpos2(stem,0);
x1l=x2l=apex_o; y1=foot; y2=x_height-foot;
podi(1); qeri(2); penstroke z1e--z2e;
%
%
%
z5.1=z2r+(2apex_o,0);
penpos5.2(stem,40); z5.2r=z5.1;
penpos5.3(stem,40);
z5.2r-z5.3r=whatever*dir-50;
y5.3r=y2+foot+apex_o;
z3=z5.3r+(0,0.5hair);
penpos4(0.8stem,0); y4=1.379x_height;
x4r=x2r+hair;
filldraw z3--z4l--z4r--z3 & cycle;
.endchar;

.cmchar "The gothic letter j";
.beginchar("j",2.889u#,1.431x_height#,2.778u#);
.adjust_fit(cap_serif_fit#+0.6u#,cap_serif_fit#-.85u#);
penpos1(stem,0); penpos2(stem,0);
x1l=x2l=apex_o; y1=foot; y2=x_height-foot;
qeri(2); penstroke z1e--z2e;
%
%
%
z5.1=z2r+(2apex_o,0);
penpos5.2(stem,40); z5.2r=z5.1;
penpos5.3(stem,40);
z5.2r-z5.3r=whatever*dir-50;
y5.3r=y2+foot+apex_o;
z3=z5.3r+(0,0.5hair);
penpos4(0.8stem,0); y4=1.379x_height;
x4r=x2r+hair;
filldraw z3--z4l--z4r--z3 & cycle;
%
%
%
z40=z1r+(apex_o,-0.5y1r); z41=(x1l-0.6hair,0);
penpos42(hair,90); z42l=(x1l-1.733stem,-d);
filldraw z1r{down}..z40 & z40{dir225}..
z42l{left} & z42l--z42r & z42r{right}..
z1l{up} & z1l--z1r & cycle;
.endchar;

.cmchar "The gothic letter k";
.beginchar("k",6.111u#,1.431x_height#,0);
.adjust_fit(cap_serif_fit#,cap_serif_fit#+.4u#);
z0=(0,0); ygoth_k(0);
.endchar;

.cmchar "The gothic letter l";
.beginchar("l",4.278u#,1.431x_height#,0);
.adjust_fit(cap_serif_fit#,cap_serif_fit#-u#);
penpos301(stem,0); penpos302(stem,0);
penpos303(stem,0); penpos304(stem,0);
penpos308(stem,60); penpos309(stem,60);
z301=(0.243w,foot); z302=(x301,0.888h);
penstroke z301e--z302e; podi(301);
%
%
%
z321=0.267[z302l,z302r]; z320l=(w,0.5[h,y302]);
penpos320(3/4hair,-135);
z322=(0.7[x321,x320],h-apex_o);
z321'=(x301r,1/4[y321,x_height]);
penpos325(0.7hair,-90); z325l=z322;
filldraw z321..z325l{right} & z325l--z325r &
z325r{left}..z321'{down} & z321'--z302r--z321 &
cycle;
penpos318(hair,45);
x318r=0;y318r=1/3[h,y321];
z321''=(x301l,0.5[y321,x_height]);
filldraw z321''{up}..{z318-z321}z318l &
z318l--z318r--z321--z302l--z321'' & cycle;
.endchar;

.cmchar "The gothic letter m";
.beginchar("m",9u#,x_height#,0);
.adjust_fit(cap_serif_fit#,cap_serif_fit#);
penpos1(stem,0); penpos2(stem,0);
penpos3(stem,0); penpos4(stem,0);
penpos5(stem,0); penpos6(stem,0);
x1l=hair;
x2=x1; x4l=x3l=x1r+1.233stem;
x6l=x5l=x3r+1.233stem;
y1=y3=y5=foot; y2=y4=y6=x_height-foot;
penstroke z1e--z2e; penstroke z3e--z4e;
penstroke z5e--z6e;
podi(1); podi(3); podi(5);
qeri(2); panwqeri(4); panwqeri(6);
.endchar;

.cmchar "The gothic letter n";
.beginchar("n",5.5u#,x_height#,0);
.adjust_fit(cap_serif_fit#,cap_serif_fit#+.2u#);
penpos1(stem,0); penpos2(stem,0);
penpos3(stem,0); penpos4(stem,0);
x1l=hair;
x2=x1; x4l=x3l=x1r+1.233stem;
y1=y3=foot; y2=y4=x_height-foot;
penstroke z1e--z2e; penstroke z3e--z4e;
podi(1); podi(3); 
qeri(2); panwqeri(4); 
.endchar;

.cmchar "The gothic letter o";
.beginchar("o",6.111u#,x_height#,0);
.adjust_fit(cap_serif_fit#-.4u#,cap_serif_fit#+0.2u#);
z0=(0,0); ygoth_o(0);
.endchar;

.cmchar "The gothic letter p";
.beginchar("p",6.111u#,x_height#,0.431x_height#);
.adjust_fit(cap_serif_fit#,cap_serif_fit#);
penpos1(stem,0); penpos2(stem,0);
penpos3(stem,0); penpos4(stem,0);
penpos8(stem,60); penpos9(stem,60);
z1=(0.243w,foot); z2=(x1,h-foot);
qeri(2); z9l=z1l-(3apex_o,0);
x7=0.359[x1r,x3l]; y7=-apex_o;
z8l=z7; z3r-z7=whatever*dir30;
x3r=w-apex_o;
z4r=(x3r,0.833x_height);
z7'=whatever[z9r,z8r]; z7'=whatever[z7,z3r];
z7''=whatever[z7,z3r]; x7''=x3l;
penstroke z1e--z2e; penstroke z8e--z9e;
penstroke z3e--z4e;
filldraw z8r--z7'--z7--z8r & cycle;
filldraw z7''--z3l--z3r--z7'' & cycle;
penpos100(hair,angle(z3r-z7)-90);
penpos101(hair,angle(z3r-z7)-90);
z100r=z7; z101r=whatever[z7,z3r]; x101l=x3r;
penstroke z100e--z101e;
%
%
%
penpos5(stem,60); z17=(x1r,0.824x_height);
z6=(0.821[x1r,x3l],x_height);
z5r=(x101r,y4); 
penpos6'(hair,angle(z6-z17)-90);
z6'l=z6; z17'-z6'r=whatever*(z17-z6);
x17'=x1r; z5.1=whatever[z17',z6'r];
z5.1-z5l=whatever*(z6-z5r);
filldraw z5r--z6--z17--z17'--z5.1--z5l--z5r
& cycle;
%
%
%
penpos6.5(hair,angle(z6-z17)-90);
z6.5l=whatever[z17,z6'l];
y6.5l=x_height+hair;
penstroke z6'e--z6.5e;
%
%
%
penpos200(stem,0); z200=(x2,-0.271x_height);
z21=0.267[z200l,z200r]; z20=(x6,0.5[-d,y200]);
penpos20(3/4hair,-45);
z22=(0.545[x21,x20],-d+apex_o);
z21'=(x1r,1/4[y21,0]);
filldraw z21..z22..{up}z20r & z20r--z20l
& z20l{down}..z21'{up} & z21'--z200r--z21 &
cycle;
penpos18(hair,angle(z9-z8));
x18r=0;y18r=1/3[-d,y21];
z21''=(x1l,0.5[y21,0]);
filldraw z21''{down}..{z18-z21}z18r &
z18r--z18l--z21--z200l--z21'' & cycle;
penstroke z200e--z1e;
.endchar;

.cmchar "The gothic letter q";
.beginchar("q",6.111u#,x_height#,0.431x_height#);
.adjust_fit(cap_serif_fit#-.3u#,cap_serif_fit#);
penpos1(stem,0); penpos2(stem,0);
penpos3(stem,0); penpos4(stem,0);
penpos8(stem,60); penpos9(stem,60);
z1=(0.243w,foot); z2=(x1,0.888h);
z9l=z1l-(apex_o,0);
x7=0.359[x1r,x3l]; y7=-apex_o;
z8l=z7; z3r-z7=whatever*dir30;
x3r=w-apex_o;
z4r=(x3r,0.88x_height); %0.833
z7'=whatever[z9r,z8r]; z7'=whatever[z7,z3r];
z7''=whatever[z7,z3r]; x7''=x3l;
penstroke z8e--z9e;
penstroke z3e--z4e;
filldraw z8r--z7'--z7--z8r & cycle;
filldraw z7''--z3l--z3r--z7'' & cycle;
penpos100(hair,angle(z3r-z7)-90);
penpos101(hair,angle(z3r-z7)-90);
z100r=z7; z101r=whatever[z7,z3r]; x101r=x3r;
penstroke z100e--z101e;
%
%
%
penpos5(stem,60); z17=(x1r,0.824x_height);
z6=(0.821[x1r,x3l],x_height);
z5r=(x101r+hair,y4); 
penpos6'(hair,angle(z6-z17)-90);
z6'l=z6; z17'-z6'r=whatever*(z17-z6);
x17'=x1r; z5.1=whatever[z17',z6'r];
z5.1-z5l=whatever*(z6-z5r);
filldraw z5r--z6--z17--z17'--z5.1--z5l--z5r
& cycle;
%
%
%
penpos2'(stem,0); z2'r=z17'; 
z31=whatever[z6,z5r]; x31=x1l;
z30=whatever[z31,z5r]; 
z30-z2'l=whatever*(z2'r-z6'r);
x34=0; z34=whatever[z5.1,z5l];
z32=(x31-0.5hair,y31+hair);
z33=(2x32,y34); z35=whatever[z2'l,z30];
z35=whatever[z34,z5.1];
penpos150(0.9hair,angle(z30-z2'l)-90);
z150l=0.5[z2'l,z30];
filldraw z2'r--z6'r--z6--z30
& flex(z30,z150r,z2'l) & z2'l--z2'r & cycle;
penstroke z1e--z2'e;
%
%
%
penpos200(stem,0); z200=(x3,-0.271x_height);
z210=0.267[z200r,z200l]; z201=(x7,0.5[-d,y200]);
penpos201(3/4hair,45);
z220=(0.545[x201,x210],-d+apex_o);
z210'=(x3l,1/4[y210,0]);
filldraw z210..z220..{up}z201l & z201l--z201r
& z201r{down}..z210'{up} & z210'--z200r--z210 &
cycle;
penpos180(hair,angle(z17-z6));
x180r=w; y180r=1/3[-d,y210];
z210''=(x3r,0.5[y210,0]);
filldraw z210''{down}..{z180-z210}z180l &
z180l--z180r--z210--z200r--z210'' & cycle;
penstroke z200e--z3e;
.endchar;

.cmchar "The gothic letter r";
.beginchar("r",4.389u#,x_height#,0);
.adjust_fit(2cap_serif_fit#+0.3u#,cap_serif_fit#);
penpos1(stem,0); z1l=(apex_o,foot);
z2'=(0.5w,-apex_o); z1'=z1l-(2apex_o,0);
penpos2(stem,0); z2=(x1,0.804x_height);
penpos3(stem,angle(z2'-z1')+90);
z3l=z2'; 
penpos4(stem,angle(z2'-z1')+90);
z4l=z1'; penstroke z1e--z2e; qeri(2);
penstroke z3e--z4e;
penpos15(hair,-60); z15r=z2';
z16-z15r=whatever*dir30; x16=w-apex_o;
x16=x16'; z16'-z15l=whatever*(z16-z15r);
z16''=whatever[z15,z16']; 
y16''=0.5[foot,y16'];
filldraw z3r{z3-z4}...z16''---z16' &
z16'--z16--z15r--z15l--z3r & cycle;
%
%
%
penpos10(hair,-60); z10r=(x1r,2/3x_height);
penpos11(1.1stem,27); z11r=(w,0.739x_height);
z12-z10l=whatever*dir60; y12=x_height+hair;
z13-z11r=whatever*(z10l-z12);
z14-z11l=whatever*(z12-z11r);
z14-z10r=whatever*(z12-z10l);
z13=whatever[z14,z11l];
filldraw z10l--z12--z11r--z13--z14--z10r--
z10l & cycle;
z15'=whatever[z10l,z12]; x15'=x10r;
unfilldraw z15'--(x15',x_height)--z12--z15'
& cycle;
.endchar;

.cmchar "The gothic letter long s";
.beginchar("s",4.389u#,11.944u#,0);
.adjust_fit(cap_serif_fit#,cap_serif_fit#);
z0=(hair,0); ygoth_s(0);
.endchar;

.cmchar "The gothic letter short s";
.beginchar(oct"140",5.2u#,x_height#,0);
.adjust_fit(cap_serif_fit#+.7u#,cap_serif_fit#+.3u#);
penpos1(hair,-45); penpos2(hair,-45);
z1r=(0,foot); z2l=(w,0.9h);
penstroke z1e--z2e;
%
% panw meroc
%
penpos3(stem,angle(z2-z1)); z3=whatever[z1l,z2l];
penpos4(stem,angle(z2-z1)); 
z4-z3=whatever*(z1l-z1r);
z4l=(-2apex_o,0.458h);
penstroke z3e--z4e;
y5=y4l; penpos5(stem,0); x5l=0;
penpos6(stem,0); x6=x5; y6=h-foot;
penstroke z5e--z6e;
penpos7(stem,60); x7=0.5w; y7r=h;
z7l-z9=whatever*dir147;
z7r-z8=whatever*dir147;
z9=whatever[z1l,z2l]; z8=whatever[z1l,z2l];
penpos10(hair,-66); z10l=whatever[z7l,z9];
x10l=x6r; penpos11(hair,-90); z11l=z6l;
penpos12(hair,angle(z8-z7r)); z12l=z7r;
filldraw z9--z7l--z7r--z8--z9 & cycle;
penstroke z11e{z6r-z6l}..{z7r-z7l}z12e;
z13=whatever[z7l,z7r]; y13=h+apex_o;
z13'=0.3[z7r,z8];
filldraw z7r--z13 & z13..{z8-z12}z13'
& z13'--z7r & cycle;
penpos14(0.4stem,0);
x14l=x2l; y14=h+hair;
filldraw z2l{z2l-z1l}..z14l{dir110} &
flex(z14l,z14+(0,apex_o),z14r) &
z14r{down}..z2r{z1r-z2r} & z2r--z2l & cycle;
z10'=whatever[z7l,z9]; x10'=0;
z10''=(z10'--z9) intersectionpoint 
(z11{right}..z12{z7r-z7l});
filldraw z10''..z7r{z7r-z7l} & z7r--z7l--
z10'' & cycle;
%
% katw meroc
%
penpos20(stem,60); z20r=(w+2apex_o,0.542h);
z21-z20r=whatever*(z12-z8);
z22-z20l=whatever*(z12-z8);
z21=whatever[z1r,z2r];
z22=whatever[z1r,z2r];
filldraw z20r--z21--z22--z20l--z20r & cycle;
penpos23(stem,0); x23r=w; y23=y20r;
penpos24(stem,0); x24=x23; y24=0.216h;%0.216h;
penstroke z24e--z23e;
penpos25(hair,-50); x25l=x24r; 
z25r-z24r=whatever*dir30;
penpos26(hair,-50); z26r=whatever[z24r,z25r];
y26r=-apex_o; penstroke z26e--z25e;
z31=whatever[z1r,z2r];
z31-z26r=whatever*dir140;
penpos27(stem,50); z27l=z26r;
z29-z27r=whatever*(z31-z27l);
z29=whatever[z1r,z2r];
z28=whatever[z26r,z25r];
z28=whatever[z29,z27r];
filldraw z31--z26r--z28--z29--z31 & cycle;
z32=whatever[z26,z25]; x32=x24l;
filldraw z32--z24r--z24l--z32 & cycle;
penpos30(0.6stem,45); x30r=x4l;
y30r=-hair;
filldraw z30r{dir135}..z1r{z2r-z1r} &
z1r--z1l & z1l{z1r-z2r}..{dir290}z30l
& z30l--z30r & cycle;
.endchar;

.cmchar "The gothic letter t";
.beginchar("t",4.389u#,1.242x_height#,0);
.adjust_fit(2cap_serif_fit#,cap_serif_fit#-u#);
z0=(0,0); ygoth_t(0);
.endchar;

.cmchar "The gothic letter u";
.beginchar("u",5.5u#,x_height#,0);
.adjust_fit(cap_serif_fit#,cap_serif_fit#+.2u#);
z0=(0,0); ligature:=false;
ygoth_u(0);
.endchar;

.cmchar "The gothic letter v";
.beginchar("v",6.111u#,x_height#,0);
.adjust_fit(cap_serif_fit#,cap_serif_fit#);
penpos1(stem,0); penpos2(stem,0);
penpos3(stem,0); penpos4(stem,0);
penpos8(stem,60); penpos9(stem,60);
z1=(0.243w,foot); z2=(x1,x_height-foot);
z9l=z1l-(2apex_o,0);
x7=0.359[x1r,x3l]; y7=-apex_o;
z8l=z7; z3r-z7=whatever*dir30;
x3r=w-apex_o;
z4r=(x3r,0.833x_height);
z7'=whatever[z9r,z8r]; z7'=whatever[z7,z3r];
z7''=whatever[z7,z3r]; x7''=x3l;
penstroke z1e--z2e; penstroke z8e--z9e;
penstroke z3e--z4e;
filldraw z8r--z7'--z7--z8r & cycle;
filldraw z7''--z3l--z3r--z7'' & cycle;
penpos100(hair,angle(z3r-z7)-90);
penpos101(hair,angle(z3r-z7)-90);
z100r=z7; z101r=whatever[z7,z3r]; x101l=x3r;
penstroke z100e--z101e;
%
%
%
penpos5(stem,60); z17=(x1r,0.824x_height);
z6=(0.821[x1r,x3l],x_height);
z5r=(x101r,y4); 
penpos6'(hair,angle(z6-z17)-90);
z6'l=z6; z17'-z6'r=whatever*(z17-z6);
x17'=x1r; z5.1=whatever[z17',z6'r];
z5.1-z5l=whatever*(z6-z5r);
filldraw z5r--z6--z17--z17'--z5.1--z5l--z5r
& cycle;
%
%
%
penpos6.5(hair,angle(z6-z17)-90);
z6.5l=whatever[z17,z6'l];
y6.5l=x_height+hair;
penstroke z6'e--z6.5e;
penpos202(hair,-45); x202l=x1l; 
y202l=1.333x_height; 
z203=(x1r,0.5[y2,x_height]);
z204=(x1l,y2-0.5stem);
penpos205(stem,45); x205=x1l;
y205l=x_height-hair;
penstroke z2e{up}..z205e{dir(angle(z205r-z205l)+90)}
..z202e{dir45};
.endchar;

.cmchar "The gothic letter w";
.beginchar("w",10.7u#,x_height#,0);
.adjust_fit(cap_serif_fit#,cap_serif_fit#-.8u#);
w:=6.111u;
penpos1(stem,0); penpos2(stem,0);
penpos3(stem,0); penpos4(stem,0);
penpos8(stem,60); penpos9(stem,60);
z1=(0.243w,foot); z2=(x1,x_height-foot);
z9l=z1l-(2apex_o,0);
x7=0.359[x1r,x3l]; y7=-apex_o;
z8l=z7; z3r-z7=whatever*dir30;
x3r=w-apex_o;
z4r=(x3r,0.833x_height);
z7'=whatever[z9r,z8r]; z7'=whatever[z7,z3r];
z7''=whatever[z7,z3r]; x7''=x3l;
penstroke z1e--z2e; penstroke z8e--z9e;
penstroke z3e--z4e;
filldraw z8r--z7'--z7--z8r & cycle;
filldraw z7''--z3l--z3r--z7'' & cycle;
penpos100(hair,angle(z3r-z7)-90);
penpos101(hair,angle(z3r-z7)-90);
z100r=z7; z101r=whatever[z7,z3r]; x101l=x3r;
penstroke z100e--z101e;
%
%
%
penpos5(stem,60); z17=(x1r,0.824x_height);
z6=(0.821[x1r,x3l],x_height);
z5r=(x101r,y4); 
penpos6'(hair,angle(z6-z17)-90);
z6'l=z6; z17'-z6'r=whatever*(z17-z6);
x17'=x1r; z5.1=whatever[z17',z6'r];
z5.1-z5l=whatever*(z6-z5r);
filldraw z5r--z6--z17--z17'--z5.1--z5l--z5r
& cycle;
%
%
%
transform metatopish;
metatopish=identity 
shifted (x3-x1,0);
addto currentpicture also currentpicture
transformed metatopish;
z201=whatever[z9r,z7'];
z201=whatever[z100l,z101l];
z200=whatever[z100l,z101l];
x200=x3l; 
unfilldraw z200--z201--(x201,y9r)--
(x200,y9r)--z200 & cycle;
%
%
%
penpos6.5(hair,angle(z6-z17)-90);
z6.5l=whatever[z17,z6'l];
y6.5l=x_height+hair;
penstroke z6'e--z6.5e;
penpos202(hair,-45); x202l=x1l; 
y202l=1.333x_height; 
z203=(x1r,0.5[y2,x_height]);
z204=(x1l,y2-0.5stem);
penpos205(stem,45); x205=x1l;
y205l=x_height-hair;
penstroke z2e{up}..z205e{dir(angle(z205r-z205l)+90)}
..z202e{dir45};
.endchar;

.cmchar "The gothic letter x";
.beginchar("x",4.389u#,x_height#,0);
.adjust_fit(2cap_serif_fit#+.3u#,cap_serif_fit#);
penpos1(stem,0); z1l=(apex_o,foot);
z2'=(0.5w,-apex_o); z1'=z1l-(apex_o,0);
penpos2(stem,0); z2=(x1,0.804x_height);
penpos3(stem,angle(z2'-z1')+90);
z3l=z2'; 
penpos4(stem,angle(z2'-z1')+90);
z4l=z1'; penstroke z1e--z2e; qeri(2);
penstroke z3e--z4e;
penpos15(hair,-60); z15r=z2';
z16-z15r=whatever*dir30; x16=w-apex_o;
x16=x16'; z16'-z15l=whatever*(z16-z15r);
z16''=whatever[z15,z16']; 
y16''=0.5[foot,y16'];
filldraw z3r{z3-z4}...z16''---z16' &
z16'--z16--z15r--z15l--z3r & cycle;
%
%
%
penpos10(hair,-60); z10r=(x1r,2/3x_height);
penpos11(1.1stem,27); z11r=(w,0.739x_height);
z12-z10l=whatever*dir60; y12=x_height+hair;
z13-z11r=whatever*(z10l-z12);
z14-z11l=whatever*(z12-z11r);
z14-z10r=whatever*(z12-z10l);
z13=whatever[z14,z11l];
filldraw z10l--z12--z11r--z13--z14--z10r--
z10l & cycle;
z15'=whatever[z10l,z12]; x15'=x10r;
unfilldraw z15'--(x15',x_height)--z12--z15'
& cycle;
%
%
%
penpos100(1.2hair,angle(z3r-z4r)); 
penpos101(hair,angle(z3r-z4r));
z100l=z4l; z100-z101=whatever*(z4r-z4l);
y101=-.8stem; penstroke z101e--z100e;
.endchar;

.cmchar "The gothic letter y";
.beginchar("y",5.5u#,x_height#,3.056u#);
.adjust_fit(cap_serif_fit#,cap_serif_fit#+.1u#);
penpos1(stem,0); penpos2(stem,0);
penpos3(stem,0); penpos4(stem,0);
x1l=hair;
x2=x1; x4l=x3l=x1r+1.233stem;
y1=foot; y2=y4=x_height-foot;
y3=0.242x_height;
penstroke z1e--z2e; penstroke z3e--z4e;
qeri(2); panwqeri(4);
penpos101(hair,-70); penpos100(hair,-70);
x101l=x4r; y101r=y3; 
z101-z100=whatever*dir18;
x100r=x1r;
penstroke z100e--z101e;
z100.5=whatever[z100,z101]; x100.5=x4l;
filldraw z100.5--z3l--z3r--z100.5 & cycle;
penpos102(1.2hair,180); 
penpos103(hair,-90); penpos104(hair,0);
z102=(x1l-0.1stem,-.5d);
z104=(0.361[x1r,x3l],-0.611d);
x103=0.522[x102,x104]; y103r=-d;
filldraw z1l{down}..z102r..z103r..z104r{up}
& z104r--z104l & z104l{down}..z103l..z102l
..z100r{z101-z100} & z100r--z1r--z1l &
cycle;
penpos200(stem,0); z200r=z104r;
filldraw z200r..z200l..z200r..cycle;
.endchar;

.cmchar "The gothic letter z";
.beginchar("z",4.306u#,x_height#,3.333u#);
.adjust_fit(cap_serif_fit#+.2u#,cap_serif_fit#+.2u#);
z0=(0,0); ygoth_z(0);
.endchar;

